GOTO ve IF Kontrol Komutları

GOTO KOMUTU

Bu komut, program çalışırken çalışmanın istenilen satıra atlamasını sağlar.

Kullanılışı;

GOTO SATIRNO

Yani GOTO deyiminin önüne yazdığımız satır numarası kaç ise, program hangi satırda olursa olsun belirtilen satırdan çalışmasına devam eder. Diyelim ki, program sırayla satırlardaki komutların gereğini yerine getirerek çalışmaya devam ederken (misal) 70 no'lu satırda GOTO 210 komutunu gördü. Bu takdirde 70 ile 210 nolu satırlar arasındaki komutları atlar 210 nolu satırdan çalışmasına devam eder.

Aşağıdaki şekilde görülen programın çalışması sonsuzdur.

10 print "merhaba, nasılsın"

20 print"sağol, iyiyim"

30 goto 10

Yukarıdaki program 10 nolu ve 20 nolu satırlardaki print komutu gereği belirtilen mesajları ekrana yazdıktan sonra 30 nolu satırdaki komut gereği tekrar 10 nolu satıra döner ve tekrar 10 ve 20 nolu satırdaki işlemleri yapar. Her seferinde 30 nolu satıra geldiğinde yeniden en başa döneceğinden bu işlem sonsuz döngü diye tabir ettiğimiz şekilde sürer gider. Ta ki programın çalışması kullanıcı tarafından durduruluncaya ya da bilgisayar kapanıncaya kadar. Bu döngüyü kesmek için Ctrl ve Pause(Break) tuşlarına beraber basınız.

Yani, bu komut anlayacağınız gibi program çalışmasını istediğimiz bölüme yönlendirmemizi sağlıyor.

IF KOMUTU

Kullanılışı;

IF Şart THEN İşlem ELSE İşlem

Bunu Türkçeleştirecek olursak;

IF Şart THEN İşlem ELSE İşlem

Eğer Şart uygunsa O zaman bu işlemi yap aksi takdirde bu işlemi yap

Bu bilgiler ışığında önce bahsettiğimiz programı yapıyoruz. Girilecek değerleri ve bilgileri bir kez daha hatırlayalım;

Mutfak eşyasının kodu : kod$

Mutfak eşyasının adı : adı$

Stok Miktarı : stok

Fiyatı : fiyat

Satılan Adet : adet

Tutarı : tutar

Kalan Stok Miktarı : kalan

Şimdi bu bilgilere göre programı üç bölüme ayıran menüyü daha önce öğrendiğimiz bütün komutları kullanarak yapıyoruz.

10 KEY OFF

20 CLS

30 LOCATE 4,30:PRINT "M E N Ü"

40 LOCATE 7,28:PRINT "1. BİLGİ GİRİŞİ"

50 LOCATE 9,28:PRINT "2. SATIŞ BİLGİLERİ"

60 LOCATE 11,28:PRINT "3. STOK BİLGİLERİ"

70 LOCATE 13,28:PRINT "4. ÇIKIŞ"

80 LINE INPUT X$

90 IF X$="1" THEN GOTO 200 ELSE 100

100 IF X$="2" THEN GOTO 500 ELSE 110

110 IF X$="3" THEN GOTO 800 ELSE 120

120 IF X$="4" THEN END ELSE GOTO 130

130 GOTO 20

200 CLS

210 LOCATE 5,5:LINE INPUT "Mutfak eşyasının kodu :",KOD$

220 LOCATE 7,5:LINE INPUT "Mutfak eşyasının adı :",ADI$

230 LOCATE 9,5:INPUT "Stok :",STOK

240 LOCATE 11,5:INPUT "Fiyatı :",FIYAT

250 LOCATE 13,5:INPUT "Satılan Adet :",ADET

260 TUTAR=FIYAT*ADET

270 KALAN=STOK-ADET

280 LOCATE 18,7:LINE INPUT "menü için enter'a basınız...",W$

290 GOTO 10

500 CLS

510 LOCATE 5,5:PRINT "Kod No : "KOD$

520 LOCATE 7,5:PRINT "Mutfak Eşyası : "ADI$

530 LOCATE 11,5:PRINT "Satılan Miktar : "ADET

540 LOCATE 13,5:PRINT "Fiyatı : "FIYAT

550 LOCATE 15,5:PRINT "Toplam Tutarı : "TUTAR

560 LOCATE 20,5:LINE INPUT "menu için enter'a basınız ...",W$

570 GOTO 10

800 CLS

810 LOCATE 5,5:PRINT "Kod No : "KOD$

820 LOCATE 7,5:PRINT "Mutfak Eşyası : "ADI$

830 LOCATE 11,5:PRINT "Mevcut : "STOK

840 LOCATE 13,5:PRINT "satılan : "ADET

850 LOCATE 15,5:PRINT "son stok durumu : "KALAN

860 LOCATE 20,5:LINE INPUT "menu için enter'a basınız ...",W$

870 GOTO 10

Yukarıdaki programın açıklaması;

10 En alt satırdaki fonksiyon (key) tanımlarını gösteren satır görüntüsünü kapatır.

20 - 70 Ekrana menü görüntüsü yazdırılır.

80 x$ değişkenine (if komutundaki şartı oluşturacak) bilgi girişinin yapılmasını sağlar,

90-120 x$ değişkenine girilen bilgiye göre programı istenilen bölüme gönderir.

130 x$ değişkenine girilen bilgiler seçeneklerden farklı ise programı yeniden seçim yapmak üzere başa döndürür.

200 - 290 Bilgi girişi programı

500 - 570 Satış Bilgileri görüntüleme programı

800 - 870 Stok Bilgileri görüntüleme programı

10. Sayfa           12. Sayfa

INDEX